ASP防SQL注入攻击技巧实例教程详解

首页

编程语言

ASP防SQL注入攻击技巧实例教程详解

热心网友

转载

2026-05-07

引言

在ASP项目中，如果SQL查询直接使用了字符串拼接，那么整个应用就向SQL注入攻击敞开了大门。这可不是危言耸听，而是无数安全事件反复验证过的现实。好在，我们手头有两件相当趁手的“武器”来加固防线：敏感词过滤与参数化语句。接下来，我们就来深入聊聊这两种方法的实战应用。

免费影视、动漫、音乐、游戏、小说资源长期稳定更新！ 👉 点此立即查看 👈

敏感词过滤

Dim Fy_Post,Fy_Get,Fy_In,Fy_Inf,Fy_Xh,Fy_db,Fy_dbstr,Kill_IP,WriteSql
'自定义需要过滤的字串,用 "|" 分隔
Fy_In = "'|;|and|(|)|exec|insert|select|delete|update|count|*|%|chr|mid|master|truncate|char|declare|exist|drop"
Kill_IP=True
WriteSql=True           '----------------------------------
Fy_Inf = split(Fy_In,"|")
'--------POST部份------------------
If Request.Form<>"" Then
    For Each Fy_Post In Request.Form
        For Fy_Xh=0 To Ubound(Fy_Inf)
            If Instr(LCase(Request.Form(Fy_Post)),Fy_Inf(Fy_Xh))<>0 Then
            Response.Redirect "/index.asp"
            Response.End
            End If
        Next
    Next
End If
If Request.QueryString<>"" Then
    For Each Fy_Get In Request.QueryString
        For Fy_Xh=0 To Ubound(Fy_Inf)
            If Instr(LCase(Request.QueryString(Fy_Get)),Fy_Inf(Fy_Xh))<>0 Then
            Response.Redirect "/index.asp"
            Response.End
            End If
        Next
    Next
End If

这段代码的核心思路很直接：在用户提交的数据（无论是POST表单还是GET参数）流入系统之初，就进行一次“安检”。它会遍历一个预定义的敏感词清单（比如“select”、“exec”、“drop”等常见的SQL关键字和特殊字符），一旦发现匹配项，立刻将请求重定向到首页或其他安全页面，从而将恶意代码拦截在数据库之外。这种方法好比一道基础的防火墙，能有效过滤掉大量初级、通用的攻击脚本。

参数化

Public Function execSqlOpen(connect,cursorType,lockType,args())
      set cmdTemp = server.CreateObject("ADODB.Command")
          cmdTemp.ActiveConnection = connect
          cmdTemp.Prepared = true
          cmdTemp.CommandText = args(0)
    Dim i
          For i = 1 To UBound(args)
             set paramTemp = cmdTemp.CreateParameter("",201,1,Len(args(i))+10,args(i))
        cmdTemp.Parameters.Append paramTemp
        Next
             set rsTemp=server.CreateObject("adodb.recordset")
          rsTemp.open cmdTemp,,cursorType,lockType
          set execSqlOpen = rsTemp
end function
Public Function execSqlExecute(connect,args())
      set cmdTemp = server.CreateObject("ADODB.Command")
          cmdTemp.ActiveConnection = connect
          cmdTemp.Prepared = true
          cmdTemp.CommandText = args(0)
    Dim i
        For i = 1 To UBound(args)
             set paramTemp = cmdTemp.CreateParameter("",201,1,Len(args(i))+10,args(i))
        cmdTemp.Parameters.Append paramTemp
        Next
             set execSqlExecute = cmdTemp.execute
end function

如果说敏感词过滤是“黑名单”机制，那么参数化查询就是更本质、更安全的“白名单”方案。它的原理是将SQL语句结构与用户输入的数据分离开来。上面这两个封装好的函数就是为此服务的。使用时，你需要将原来的SQL字符串拼接逻辑，改造为使用参数数组的形式。

具体实施时，有几个关键点需要牢记：

1. 原代码使用Recordset.Open的地方，改用execSqlOpen函数（注意，如果原代码有调用close，需保留）；原代码使用Connection.Execute或Command.Execute的地方，改用execSqlExecute函数（此处无需close）。
2. 需要返回记录集（Recordset）的，用set语句接收返回值；仅仅执行操作的（如Update、Insert），用call调用即可。
3. 有一种特殊情况：表名本身需要动态拼接。由于参数化占位符不能用于表名、列名等数据库对象，这部分仍需保留原始的字符串拼接方式。
4. 对于使用LIKE进行模糊查询的情况，技巧是在SQL语句内部使用“?”占位，然后在外部将通配符“%”与关键词拼接好，再将整个字符串作为参数传入。

听起来有点抽象？看下面的例子就一目了然了：

open普通查询

sql="select * from table where column='"&column&"'"
set rs=server.CreateObject("ADODB.recordset")
rs.Open sql,conn,1,1
=>
dim args
args = Array("select * from table where column = ?",column)
set rs = execSqlOpen(conn,1,1,args)

动态参数查询

sql="select * from table where 1=1 and column1='"&request("column1")&"'"
if column2<>"" then
sql=sql&" and column2 like '%"&column2&"%'"
end if
if column3<>"" then
sql=sql&" and column3 ="&column3&""
end if
sql=sql&" order by column4 desc;"
Set rs= Server.CreateObject("ADODB.Recordset")
rs.open sql,conn,1,1
=>
dim args
args = Array("select * from table where 1=1 and column1=?",request("column1"))
if column2<>"" then
args(0)=args(0)&" and column2 like ?"
ReDim Preserve args(UBound(args)+1)
args(UBound(args)) = "%"&column2&"%"
end if
if column3<>"" then
args(0)=args(0)&" and column3 =?"
ReDim Preserve args(UBound(args)+1)
args(UBound(args)) = column3
end if
args(0)=args(0)&" order by column4 desc;"
set rs = execSqlOpen(conn,1,1,args)

table动态

Set Rs_t=Conn.Execute("Select column From "&table&" where column1="&column1)
=>
dim args
args = Array("Select column From "&table&" where column1=?",column1)
set Rs_t = execSqlExecute(conn,args)

请注意这个例子：表名（table变量）是动态拼接的，保留了原始字符串方式；而查询条件（column1）则使用了参数“?”占位，这是标准做法。

执行查询

set rs=conn.execute("select * from table where column="&request("column"))
=>
dim args
args = Array("select * from table where column = ?",request("column"))
set rs = execSqlExecute(conn,args)

执行更新

conn.execute("update table set column = '"&column&"'")
=>
dim args
args = Array("update table set column = ?",column)
call execSqlExecute(conn,args)

总的来说，敏感词过滤提供了第一层快速防御，而参数化查询则是从根源上杜绝SQL注入的“银弹”。对于遗留的ASP项目进行安全加固，将这两种方法结合使用，能显著提升应用程序的安全性。希望以上的实例详解，能为你提供清晰、可操作的改造路径。

来源:https://www.jb51.net/program/307234bd2.htm

免责声明：游乐网为非赢利性网站，所展示的游戏/软件/文章内容均来自于互联网或第三方用户上传分享，版权归原作者所有，本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容，请联系youleyoucom@outlook.com。

上一篇：NET应用Docker部署中v指令参数详解下一篇：ASP.NET MVC头像上传功能实现教程EntityFramework图片存储方法

热门推荐

web3.0

Bitget交易所2026年发展前景与市场排名深度解析

2026年，Bitget在交易所排行榜上展现出强劲的竞争力。其表现主要体现在用户资产安全体系的持续加固、多元化产品矩阵的成熟与创新，以及在合规与全球化布局上的显著进展。平台通过优化现货与衍生品交易体验，并深化Web3生态建设，巩固了其在行业中的领先地位，获得了市场与用户的广泛认可。

热心网友

05.07

编程语言

NET开发中HttpClient使用避坑指南与最佳实践详解

HttpClient的7个常见陷阱与规避指南在 NET 生态里进行项目开发，HttpClient 几乎是调用外部 API 绕不开的一个工具。它的上手门槛很低，用起来很顺手，但恰恰是这份“简单”，让不少开发者放松了警惕。如果不清楚它内部的运作机制，一不小心就可能掉进坑里，轻则请求失败，重则引发服务

热心网友

05.07

编程语言

NETCore与Linux服务器时间同步问题的多种解决方案详解

如何解决 NET Core项目与Linux服务器之间的时间同步问题导语搞分布式系统的开发者，多少都踩过时间不同步的“坑”。这事说大不大，说小不小——日志对不上、订单乱取消、交易出岔子，追根溯源，往往是几台机器的时间“各走各的”。尤其是在 NET Core应用遇上Linux服务器的场景，时区、格式

热心网友

05.07

编程语言

NET 4.7 如何使用 NLog 将日志记录到数据库

1 首先安装必要的NuGet包第一步，咱们得把项目里需要的“砖瓦”——也就是那几个关键的NuGet包——给准备好。具体是下面这几个： NLog：日志记录的核心库。 NLog Config (可选)：如果你想让配置文件自动生成，可以加上这个。当然，别忘了根据你用的数据库类型，安装对应的提供程序。

热心网友

05.07

编程语言

NETCore消息队列RabbitMQ实现方法与代码示例

在 NET Core 中玩转 RabbitMQ：从零搭建可靠的消息队列消息队列是现代应用解耦和异步通信的基石，而 RabbitMQ 无疑是这个领域的明星选手。它基于 AMQP 协议，为不同应用程序间的可靠消息传递提供了强大支持。今天，我们就来深入聊聊，如何在 NET Core 环境中，亲手搭建

热心网友

05.07